[♣_Henrique_♣]

Boa noite a todos!

estou com um probleminha aqui, ja procurei bastante e não encontrei a solução..

Tenho um input text onde a pessoa deve adicionar seu e-mail p/ assinar newsletter.
Dentro desse campo, eu dexei o valor "Email:", preciso fazer com que esse valor suma quando a pessoa clicar sobre o campo. E que ele volte quando clicar fora.

Será que alguem pode me ajudar? to usando o actionscript 3.0

Grato desde já :)/>

[Rodrigo Pixel]

Utilize o evento FocusEvent.FOCUS_IN pra quando cursor focar sobre o objeto você faz algo, por exemplo, verifica a condição do campo, se está vazio, preenchido ou com texto padrão(ex: "Email"). E o FocusEvent.FOCUS_OUT é usado quando o cursor sair do foco do objeto, você faz a mesma verificação de campo.

No exemplo abaixo cria no stage um texto input com nome de instância campo. e insira código no 1º frame:

var txtPadrao:String = "Email"; //defina aqui mensagem que vai ficar no campo

campo.text = txtPadrao;
campo.addEventListener(FocusEvent.FOCUS_IN, onFocusIn); //ativa evento

function onFocusIn(e:FocusEvent):void
{
	trace("\n**** click campo  - focus in");
	
	campo.removeEventListener(FocusEvent.FOCUS_IN, onFocusIn); //remove evento
	
	verificaCampo();
}

function onFocusOut(e:FocusEvent):void
{
	trace("\n**** click stage - focus out");
	
	campo.removeEventListener(FocusEvent.FOCUS_OUT, onFocusOut); //remove evento
	
	verificaCampo();
}

//verifica se está vazio, com texto padrão ou preenchido
function verificaCampo():void
{
	if(campo.text == "")
	{
		campo.addEventListener(FocusEvent.FOCUS_IN, onFocusIn);  //ativa evento
		campo.text = txtPadrao;
		
		trace("\n* campo com texto padrão");
	}
	else if(campo.text == txtPadrao)
	{
		campo.addEventListener(FocusEvent.FOCUS_OUT, onFocusOut);  //ativa evento
		campo.text = "";
		
		trace("\n* campo vazio");
	}
	else
	{
		campo.addEventListener(FocusEvent.FOCUS_OUT, onFocusOut); //ativa evento
		
		trace("\n* campo está preenchido");
	}
}

Abraço.

[♣_Henrique_♣]

Funcionou aqui, certinho! :D/>

VALEU MESMO!