[xanburzum]

Este código lhe permite que usuários indiquem a sua pagina aos amigos via email atravez de sua pagina.

<%
Dim objCDONTS             	' objeto de Email 
Dim strFromName           	' para quem
Dim strFromEmail, strToEmail  ' endereço de Email
Dim strSubject, strBody   	' Mensagem
Dim strThisPage           	' URL
Dim strReferringPage      	' URL da página de reenvio
Dim bValidInput           	' Um booleano que indica os parâmetros válidos

' Recuperar esse nome da página e nome da página referente
strThisPage  	= Request.ServerVariables("SCRIPT_NAME")
strReferringPage = Request.ServerVariables("HTTP_REFERER")

' Debugging lines:
'Response.Write strThisPage & "<BR>" & vbCrLf
'Response.Write strReferringPage & "<BR>" & vbCrLf

' Lê e define os valores iniciais dos parâmetros nossa mensagem
strFromName  = Trim(Request.Form("txtFromName"))
strFromEmail = Trim(Request.Form("txtFromEmail"))
strToEmail   = Trim(Request.Form("txtToEmail"))
strSubject   = "Check out ASP 101!"
strBody  	= Trim(Request.Form("txtMessage"))



If strBody = "" Then
	If strReferringPage = "" Or InStr(1, strReferringPage, "www.sua página.com", 1) = 0 Then
		strBody = ""
		strBody = strBody & "Eu encontrei um site,e pensei que você gostaria de ver:" & vbCrLf
		strBody = strBody & vbCrLf
		strBody = strBody & "   http://www.sua página.com" & vbCrLf
	Else
		strBody = ""
		strBody = strBody & "Encontrei um artigo,e pensei que você gostaria de ver:" & vbCrLf
		strBody = strBody & vbCrLf
		strBody = strBody & "   " & strReferringPage & vbCrLf
	End If
End If
	
' Validação rápida só para garantir que os nossos parâmetros são um pouco válido
bValidInput = True
bValidInput = bValidInput And strFromName <> ""
bValidInput = bValidInput And IsValidEmail(strFromEmail)
bValidInput = bValidInput And IsValidEmail(strToEmail)

'Se válida enviar e-mail e mostrar o / w forma mostrar
If bValidInput Then
	' Montar o nosso objeto de e-mail e enviar a mensagem
	Set objCDONTS = Server.CreateObject("CDONTS.NewMail")
	objCDONTS.From	= strFromName & " <" & strFromEmail & ">"
	objCDONTS.To  	= strToEmail
	objCDONTS.Subject = strSubject
	objCDONTS.Body	= strBody
	objCDONTS.Send
	Set objCDONTS = Nothing

	' Mostrar a nossa mensagem de agradecimento
	ShowThanksMsg
Else
	If "http://" & Request.ServerVariables("HTTP_HOST") & strThisPage = strReferringPage Then
		Response.Write "Houve um erro. Por favor, verifique as entradas:" & "<BR>" & vbCrLf
	End If
	' Mostrar a nossa forma de recuperação de informação
	ShowReferralForm strThisPage, strFromName, strFromEmail, strToEmail, strBody
End If
%>


<%

Function IsValidEmail(strEmail)
	Dim bIsValid
	bIsValid = True
	
	If Len(strEmail) < 5 Then
		bIsValid = False
	Else
		If Instr(1, strEmail, " ") <> 0 Then
			bIsValid = False
		Else
			If InStr(1, strEmail, "@", 1) < 2 Then
				bIsValid = False
			Else
				If InStrRev(strEmail, ".") < InStr(1, strEmail, "@", 1) + 2 Then
					bIsValid = False
				End If
			End If
		End If
	End If

	IsValidEmail = bIsValid
End Function


Sub ShowReferralForm(strPageName, strFromName, strFromEmail, strToEmail, strBody)
	
	%>
	<FORM ACTION="<%= strPageName %>" METHOD="post" name=frmReferral>
	<TABLE BORDER="0">
	<TR>
		<TD VALIGN="top" ALIGN="right"><STRONG>Seu Nome:</STRONG></TD>
		<TD><INPUT TYPE="text" NAME="txtFromName" VALUE="<%= strFromName %>" SIZE="30"></TD>
	</TR>
	<TR>
		<TD VALIGN="top" ALIGN="right"><STRONG>Seu E-mail:</STRONG></TD>
		<TD><INPUT TYPE="text" NAME="txtFromEmail" VALUE="<%= strFromEmail %>" SIZE="30"></TD>
	</TR>
	<TR>
		<TD VALIGN="top" ALIGN="right"><STRONG>E-mail de indicação:</STRONG></TD>
		<TD><INPUT TYPE="text" NAME="txtToEmail" VALUE="<%= strToEmail %>" SIZE="30"></TD>
	</TR>
	<TR>
		<TD VALIGN="top" ALIGN="right"><STRONG>Mensagem:</STRONG></TD>
		<TD><TEXTAREA NAME="txtMessage" COLS="50" ROWS="5" WRAP="virtual" READONLY><%= strBody %></TEXTAREA>
	</TR>
	<TR>
		<TD></TD>
		<TD><INPUT TYPE="reset" VALUE="Limpar" name=rstReferral>&nbsp;&nbsp;<INPUT TYPE="submit" VALUE="Enviar E-mail" name=subReferral></TD>
	</TR>
	</TABLE>
	</FORM>
	<%
	'<P>A mensagem a ser enviada:</P>
	'<P><B>Assunto:</B> < %= strSubject % ></P>
	'<P><B>Corpo:</B> < %= strBody % ></P>
End Sub

Sub ShowThanksMsg()
	%>
	<P>Sua mensagem foi enviada. Obrigado por ajudar-nos.</P>
	<%
End Sub
%>