[xanburzum]

Há momentos em que você precisa ter o log dos dados que está sendo passado para uma página através de uma operação de post (já que usando uma operação get expõe os dados como parte da querystring) e armazená-lo para posterior análise, este script analisa os logs doservidor.

<%
Option Explicit

Dim objFSO, objStream
Dim i

Const ForAppending = 8

Const bAudit_ServerVars = True
Const bAudit_FormData = True

Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objStream = objFSO.OpenTextFile( Server.MapPath( Request.ServerVariables("SCRIPT_NAME") ) & ".log" , ForAppending, True )

objStream.WriteLine "Date: " & Now()
objStream.WriteLine "Script: " & Request.ServerVariables("SCRIPT_NAME")
objStream.WriteLine ""

If bAudit_ServerVars Then
    objStream.WriteLine "Server Variables:"

    'Ciclo através de todos os itens que compõem o servidor
 'coleção de variáveis
    For i = 1 To Request.ServerVariables.Count
'Guarde o nome da chave e o valor do item associado a
'variável
   	 objStream.WriteLine "'" & Request.ServerVariables.Key(i) & "' = '" & Request.ServerVariables.Item(i) & "'"
   	 
    Next
End If

If bAudit_FormData Then
    'Verifique se os dados foi fornecido através do formulário
    If Request.Form.Count > 0 Then

   	 objStream.WriteLine ""
   	 objStream.WriteLine "Form Data:"

   	 'Desde que parecem ter dados do ciclo, através de todos os itens que nos são fornecidos,
 'Escrever o nome da chave eo valor do item
   	 For i = 1 To Request.Form.Count
   		 objStream.WriteLine "'" & Request.Form.Key( i ) & "' = '" & Request.Form.Item( i ) & "'"
   	 Next

    End If
End If

objStream.WriteLine ""

objStream.Close

Set objStream = Nothing
Set objFSO = Nothing
%>