[Gui Mello]

Bom dia galera, sou iniciante e preciso de uma grande ajuda..
Faço matemática e preciso fazer um pequeno software para o ensino de geometria plana.
Já está quase pronto, mas falta um detalhe que não tenho a menor ideia de como fazê-lo
Tenho o flash mx instalado.
vou inserir vários objetos no palco e preciso que ele sejam girados 90 graus [para qualquer sentido] quando clico com o mouse e uma tecla em conjunto,
depois disso esse objeto será arrastado até outra parte do palco.
O problema é que não sei como fazer ele girar...

Será que alguém pode me ajudar? estou desesperado e preciso fazer isso,
Desde já agradeço!

[RONYTORRES]

Explica melhor, você quer que ele gire para qualquer sentido, quando clica com o mouse nele ou em outro objeto?
Isso ficou meio confuso.

Para rotacionar um movieClip, utilize a propriedade rotation, como no exemplo abaixo:

my_mc._rotation = 90;

[Gui Mello]

RONYTORRES, on 24 August 2011 - 11:17 AM, said:

Explica melhor, você quer que ele gire para qualquer sentido, quando clica com o mouse nele ou em outro objeto?
Isso ficou meio confuso.

Para rotacionar um movieClip, utilize a propriedade rotation, como no exemplo abaixo:

my_mc._rotation = 90;

Tipo Assim..

Vou criar vários objetos (que ficarão soltos no palco)
Eles serão movidos para outra área do palco
Mas para aumentar a dificuldade dos alunos, alguns objetos poderão ser girados (no caso 90º)
Daí preciso de um código que os faça girar, mas não em clique comum,
pois só o clique do mouse servirá para arrastá-lo
preciso de um código que seja combinado com alguma tecla (por ex. Alt+clique)

Será que consegues me ajudar?
Obrigado

[Rodrigo Pixel]

Segue um exemplo em AS3:

No stage tem apenas 3 mcs com nomes de instância: mc1, mc2, mc3. Todos estão cadastrados em um array pra usar loop for e aplicar eventos de mouse etc.

Para girar objeto:
Passe o mouse sobre objeto, segure a tecla ctrl e utilize scroll do mouse para girar.


AS3:

import flash.ui.Keyboard;
import flash.events.KeyboardEvent;
import flash.events.MouseEvent;


/****************************
 * VARIABLES
 ***************************/
 
var girar:Boolean = false; //esse valor só fica true quando a tecla "ctrl" é pressionada
var mcList:Array = [mc1, mc2, mc3]; //cadastra aqui todos os nomes de instâncias de movieclip que etsiver no stage


//COMEÇA AQUI!
init();



/****************************
 * EVENTS
 ***************************/

//eventos do teclado aplicado ao stage pra saber quando foi pressionado e liberado uma tecla
stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);



/****************************
 * FUNCTIONS
 ***************************/

//começa aqui
function init():void
{
	addEvent(mcList); //adiciono evento de mouse pra todos objetos da lista
}

//aplica eventos de mouse em cada objeto da lista de movieclips
function addEvent(list:Array):void
{
	var mc:MovieClip; //movieclip atual da lista
	var len:uint = list.length; //quantidade de objetos da lista
	
	//loop...
	for(var i:uint=0; i<len; ++i)
	{
		mc = MovieClip(list[i]); //cast, certifica que o objeto da lista array será do tipo movieclip
		mc.addEventListener(MouseEvent.MOUSE_WHEEL, onMouseWheel); //quando usar scroll
		mc.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); //quando pressionar o mouse
		mc.addEventListener(MouseEvent.MOUSE_UP, onMouseUp); //quando soltar a tecla do mouse
		mc.buttonMode = true; //muda cursor do mouse para "mão".
	}
}


function onMouseDown(e:MouseEvent):void
{
	var mc:MovieClip = MovieClip(e.currentTarget); //pega movieclip atual
	
	mc.startDrag(); //começa arrastar objeto
	addChild(mc);  //deixa na frente  dos outros quando arrastado
}

function onMouseUp(e:MouseEvent):void
{
	var mc:MovieClip = MovieClip(e.currentTarget); //pega movieclip atual
	mc.stopDrag(); //para de arrastar objeto
}

function onMouseWheel(e:MouseEvent):void
{
	var mc:MovieClip = MovieClip(e.currentTarget); //pega movieclip atual
	
	//se girar == true, então pode girar objeto
	if(girar)
		mc.rotation += e.delta*5; //força do giro scroll x 5 pixels
}

function onKeyDown(e:KeyboardEvent):void
{
	//se for a tecla ctrl que está presisonada
	if(e.keyCode == Keyboard.CONTROL)
		girar = true; //pode girar
}

function onKeyUp(e:KeyboardEvent):void
{
	//se foi a tecla ctrl que foi liberada
	if(e.keyCode == Keyboard.CONTROL)
		girar = false; //não gira
}

Arquivo CS4:
http://www.mediafire...96ccnnanxi7cjd9


Abraço.

[Gui Mello]

Bah, Rodrigo

Isso me ajudou muito, obrigado mesmo!!

Abraço

Gui Mello