[edergabriel]

O código abaixo gera uma sequência de 4 movieclips no eixo x. Eu preciso que fique mais 3 linhas dessas no eixo y. Só que eu não consigo, quem puder me ajudar, eu agradeço, obrigado!

for (var i:int = 0; i < 4; i++)
{
myArray[i] = new Coluna();
teste = 0;

while (teste==0)
{
//displayRandomNumber();
//myArray[i].x += posicaoX;
myArray[i].x += 100 * i;
teste = 1;

}

trace(i);



addChild(myArray[i]);

} 

[Rodrigo Pixel]

Veja se isso te ajuda:

Criei mc com linkage nomeado pra Coluna.

var lista:Array = []; 	//lista de mcs
var numLinha:uint = 4;	//numero de linhas
var numColuna:uint = 3;	//numero de colunas
var spaceX:Number = 5; 	//espaço de pixels entre os objetos
var spaceY:Number = 5; 	//espaço de pixels entre os objetos

//crio um container que vai receber todos os mc adicionados pra poder posicionar depois
var container:MovieClip = new MovieClip();
container.x = 200; //posiciona o container no stage
container.y = 100;
addChild(container); //add container no stage


//adiciona todos os mcs  no container alvo
adicionaMc(numLinha, numColuna, container);



//basta passar o numero de linha e coluna que quer criar
function adicionaMc(linha:uint, coluna:uint, alvo:MovieClip):void
{
	var mc:MovieClip; //mc que vai ser adicionado via código
	
	//cria a linha de mc...
	for(var i:uint=0; i<linha; ++i)
	{
		//cria a coluna de mc...
		for(var j:uint=0; j<coluna; ++j)
		{
			mc = new Coluna();	//linkage na biblioteca do mc
			mc.x = i * (mc.width + spaceX); 	//posiciona x
			mc.y = j * (mc.height + spaceY); 	//posiciona y
			alvo.addChild(mc);					//add no container
			
			//cadastra o mc no array pra poder recuperar depois se quiser
			lista.push(mc);
		}
	}
}

Abraço.