[xanburzum]

Este script foi criado para registrar automaticamente todas as informações relevantes que são passadas através de um post, que opera sem uma interface, uma vez que tem apenas um propósito que é o de registrar automaticamente os dados que é enviado a ele para um arquivo de texto.

<%


Option Explicit

Dim objFSO, objStream
Dim i

Const ForAppending = 8

Const bAudit_ServerVars = True
Const bAudit_FormData = True

Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objStream = objFSO.OpenTextFile( Server.MapPath( Request.ServerVariables("SCRIPT_NAME") ) & ".log" , ForAppending, True )

objStream.WriteLine "Data: " & Now()
objStream.WriteLine "Script: " & Request.ServerVariables("SCRIPT_NAME")
objStream.WriteLine ""

If bAudit_ServerVars Then
        objStream.WriteLine "Server Variables:"

        For i = 1 To Request.ServerVariables.Count

                
                objStream.WriteLine "'" & Request.ServerVariables.Key(i) & "' = '" & Request.ServerVariables.Item(i) & "'"
                
        Next
End If

If bAudit_FormData Then
        
        If Request.Form.Count > 0 Then

                objStream.WriteLine ""
                objStream.WriteLine "Form Data:"

                
                For i = 1 To Request.Form.Count
                        objStream.WriteLine "'" & Request.Form.Key( i ) & "' = '" & Request.Form.Item( i ) & "'"
                Next

        End If
End If

objStream.WriteLine ""

objStream.Close

Set objStream = Nothing
Set objFSO = Nothing
%>