CREATE TABLE guestbook (
id INT(5) NOT NULL AUTO_INCREMENT,
nome TEXT,
email TEXT,
DATA VARCHAR(10),
comentario TEXT,
PRIMARY KEY (id)
);

<?php
/* Conectamos ao MySQL */
$connection = mysql_connect("seu host", "seu usuario", "sua senha") or die ('Erro ao Conectar ao Banco de dados');
/* Selecionamos o Banco de Dados */
$db = mysql_select_db("tutoriais") or die ("Não foi possível localizar o banco de dados");
/* Buscamos o nome, email e comentarios da tabela guestbook */
$consulta = mysql_query("SELECT id,nome,email,data,comentario FROM guestbook ORDER BY id DESC");
/* Retorna o número de linhas do resultado */
$row=mysql_num_rows($consulta);
/* Verificamos se retornou algum resultado */
if($row>0){
/* Manda a mensagem para o Flash */
print "&amp;erroMensagem=0";
/* Começamos a criar o arquivo XML */
$conteudo = "<?xml version='1.0'?><guest>";
/* Para cada item retornado */
for($i=0; $i<$row; $i++) {
/* Recuperamos os Nomes */
$nome = mysql_result($consulta,$i,"NOME");
/* Recuperamos os E-mails */
$email = mysql_result($consulta,$i,"EMAIL");
/* Recuperamos as Datas */
$data = mysql_result($consulta,$i,"DATA");
/* Recuperamos os Comentarios */
$comentario = mysql_result($consulta,$i,"COMENTARIO");
/* Inserimos os valores recuperados nas respectivas tags */
$conteudo .= "<dados><nome>";
$conteudo .= $nome;
$conteudo .= "</nome><email>";
$conteudo .= $email;
$conteudo .= "</email><data>";
$conteudo .= $data;
$conteudo .= "</data><comentario>";
$conteudo .= $comentario;
$conteudo .= "</comentario></dados>";
}
/* Fechamos a tag guest */
$conteudo .= "</guest>";
/* Se existir, abrimos o arquivo guest.xml para leitura e escrita */
/* Se não existir criamos o arquivo guest.xml */
$ponteiro = fopen("guest.xml", "w");
/* Escremos o conteúdo dentro do arquivo selecionado */
/* Codificamos para UTF8 os campos para não dar problemas com acentuação */
fwrite($ponteiro, utf8_encode($conteudo));
/* Fechamos o arquivo */
fclose($ponteiro);
/* Se não retornou nenhum resultado */
} else {
/* Manda a mensagem de erro para o Flash */
print "&erro=Não existe nenhum registro no Guestbook!&erroMensagem=1";
}
/* Selecionando a Ação */
$action = $_GET['action'];
/* Seleciona a Ação */
switch ("$action") {
/* Caso seja ação cadastrar */
case 'cadastrar':
/* Variáveis vindas do Flash pelo método POST */
/* Codificamos para ISO-8859-1 */
$nome = utf8_decode(@$_POST['nome']);
$email = utf8_decode(@$_POST['email']);
$comentario = utf8_decode(@$_POST['comentario']);
/* Deixamos a data com o formato Dia/Mes/Ano */
$data = date("d/m/Y");
/* Inserimos os dados no Banco de Dados */
$cadastra = mysql_query("INSERT INTO guestbook (nome,email,data,comentario) VALUES ('$nome','$email','$data','$comentario')") or die(mysql_error());
/* Manda a mensagem de Cadastro efetuado com Sucesso para o Flash */
print "&mensagem=Obrigado por Assinar o Guest Book&enviado=1";
break;
}
?>

/* Importamos a Classe Tween */
import mx.transitions.Tween;
import mx.transitions.easing.*;
/* Listener para o Mouse */
var mouseListener:Object = new Object();
/* Coloca no tamanho normal */
_xscale = _yscale=100;
/* Pode ser um movieclip ou um textfield */
var alvo = _parent[alvo];
/* Posição inicial do movieclip em y */
var sy:Number = alvo._y;
/* Altera o tamanho da barra */
track._height = track_height;
/* Tira a maozinha dos botões */
btn_baixo.useHandCursor = btn_cima.useHandCursor=pan.useHandCursor=track.useHandCursor=false;
/* Mínimo em _y q o pan pode ir */
var miny:Number = Math.round(track._y);
/* Máximo em _y q o pan pode ir */
var maxy:Number = Math.round((track._y+track._height)-pan._height);
/* Quando o cara pressionar o botão de cima */
btn_cima.onPress = function() {
	/* Chamamos a função mover */
	mover();
	/* Deixamos a variável subindo igual a true */
	subindo = true;
	/* Deixamos a variável descendo igual a false */
	descendo = false;
};
/* Quando tirar o mouse*/
btn_cima.onRelease = btn_cima.onReleaseOutside=function () {
	/* Deixamos a variável subindo e descendo igual a false */
	subindo = descendo=false;
	/* Deletamos o onEnterFrame */
	delete _root.onEnterFrame;
};
/* Quando o cara pressionar o botão de baixo */
btn_baixo.onPress = function() {
	/* Chamamos a função mover */
	mover();
	/* Deixamos a variável descendo igual a true */
	descendo = true;
	/* Deixamos a variável subindo igual a false */
	subindo = false;
};
/* Quando tirar o mouse */
btn_baixo.onRelease = btn_baixo.onReleaseOutside=function () {
	/* Deixamos a variável descendo e subindo igual a false */
	descendo = subindo=false;
	/* Deletamos o onEnterFrame */
	delete _root.onEnterFrame;
};
/* Quando pressionar o pan */
pan.onPress = function() {
	/* Inicia o arrastamento */
	startDrag(this, false, this._x, miny, this._x, maxy);
	/* Chamamos a função mover */
	mover();
};
/* Quando soltar o mouse */
pan.onRelease = pan.onReleaseOutside=function () {
	/* Para o arrastamento */
	stopDrag();
	/* Deletamos o onEnterFrame */
	delete _root.onEnterFrame;
};
/* Quando pressionar o track */
track.onPress = function() {
	/* Chamamos a função mover */
	mover();
	/* Move o pan */
	pan._y = _ymouse-pan._height/2;
	/* Se o pan passar do valor máximo volta para o máximo */
	if (pan._y>=maxy) {
		pan._y = maxy;
	}
	/* Se o pan passar do valor mínimo volta para o mínimo */ 
	if (pan._y<=miny) {
		pan._y = miny;
	}
};
/* Ao girar da bolinha do Mouse */
mouseListener.onMouseWheel = function(delta) {
	/* Verificamos se o Mouse está em cima das frases ou do ScrollBar */
	if (_parent.mascara.hitTest(_root._xmouse, _root._ymouse) || _parent.scrollBar.hitTest(_root._xmouse, _root._ymouse)) {
		/* Chamamos a função mover */
		mover();
		/* Se delta for igual a 3 sobe, senão desce*/
		if (delta == 3) {
			/* Se não estiver a ponto de ir além do que pode */
			if (pan._y-1>miny) {
				pan._y -= 5;
			} else {
				pan._y = miny;
				/* Deletamos o onEnterFrame */
				delete _root.onEnterFrame;
			}
		} else {
			/* Se não estiver a ponto de ir além do que pode */
			if (pan._y+1<maxy) {
				pan._y += 5;
			} else {
				pan._y = maxy;
				/* Deletamos o onEnterFrame */
				delete _root.onEnterFrame;
			}
		}
	} else {
		/* Deletamos o onEnterFrame */
		delete _root.onEnterFrame;
	}
};
/* Cria o onEnterFrame */
function mover() {
	_root.onEnterFrame = function() {
		/* Se estiver subindo */
		if (subindo) {
			/* Se não estiver a ponto de ir além do que pode */
			if (pan._y-1>miny) {
				pan._y -= 5;
			} else {
				pan._y = miny;
				/* Deletamos o onEnterFrame */
				delete _root.onEnterFrame;
			}
		}
		/* Se estiver descendo */ 
		if (descendo) {
			/* Se não estiver a ponto de ir além do que pode */
			if (pan._y+1<maxy) {
				pan._y += 5;
			} else {
				pan._y = maxy;
				/* Deletamos o onEnterFrame */
				delete _root.onEnterFrame;
			}
		}
		/* Calcula */ 
		var s:Number = ((pan._y-miny)/(maxy-miny))*100;
		var p:Number = (alvo._height-mascara)/100;
		/* Movemos o alvo */
		var tw:Tween = new Tween(alvo, "_y", Back.easeOut, alvo._y, sy-(p*s), 1, true);
	};
}
/* Adicionamos o listener ao Mouse */
Mouse.addListener(mouseListener);

/* Ocultamos os itens do menu de contexto */
Stage.showMenu = false;
/* Paramos o filme */
stop();
/* Mensagem de Carregamento */
statusGuest.text = "Carregando Mensagens";
/* Deixamos o ScrollBar invisível */
scrollBar._visible = false;
/* Definimos a máscara */
vazio.setMask(mascara);
/* Quantidade de colunas desejada */
var quantidadeColuna:Number = 1;
/* Quantidade de linhas desejadas */
var quantidadeLinha:Number = 20;
/* Quantidade de páginas */
var quantidadePagina:Number = 0;
/* Deixamos linhaAtual e colunaAtual igual a 0 */
var linhaAtual:Number, colunaAtual:Number = 0;
/* Criamos um LoadVars que recebe as informações do PHP */
var objRecebe:LoadVars = new LoadVars();
/* Criamos um novo XML */
var xml:XML = new XML();
/* Ignoramo os espaços em branco */
xml.ignoreWhite = true;
/* Carregamos o arquivo PHP evitando o Cache da máquina */
objRecebe.load("http://natan-alves.t35.com/guestMx.php?cache="+getTimer());
/* Ao carregar o arquivo PHP */
objRecebe.onLoad = function(ok) {
	/* Se for ok */
	if (ok) {
		/* Se a variavel erroMensagem for igual a 1 */
		if (this.erroMensagem == 1) {
			/* Mostramos qual o erro */
			statusGuest.text = this.erro;
			/* Se não */
		} else {
			/* Apagamos o campo statusGuest */
			statusGuest.text = "";
			/* Carregamos o arquivo XML evitando o Cache da máquina */
			xml.load("http://natan-alves.t35.com/guestMx.xml?cache="+getTimer());
		}
		/* Se não for ok */
	} else {
		/* Mostramos a mensagem de erro */
		statusGuest.text = "Erro ao carregar os arquivos";
	}
};
/* Ao carregar do arquivo XML */
xml.onLoad = function(ok) {
	/* Se for ok */
	if (ok) {
		/* Apagamos o campo statusGuest */
		statusGuest.text = "";
		/* Dizemos qual o primeiro nó */
		xmlNode = this.firstChild;
		/* Criamos uma variável para o total de itens no XML */
		total = xmlNode.childNodes.length;
		/* Quantidade de página é igual a total dividido por quantidade de linha vezes coluna */
		quantidadePagina = Math.ceil((total)/(quantidadeColuna*quantidadeLinha));
		/* Se quantidade de páginas for maior que 1 */
		if (quantidadePagina>1) {
			/* Chamamos a função criaPaginacao */
			criaPaginacao();
			/* Se quantidade de página for menor que 1 */
		} else {
			/* Chamamos a função preencher */
			preencher();
			/* Deletemos a função criaPaginacao */
			delete criaPaginacao();
			/* Removemos o MovieClip paginação */
			paginacao.unloadMovie();
		}
		/* Se não for ok */
	} else {
		/* Mostramos a mensagem de erro */
		statusGuest.text = "Erro ao carregar os arquivos";
	}
};
/* Função preencher */
function preencher() {
	/* Chamamos o MovieClip recebe no MovieClip vazio */
	var mc:MovieClip = vazio.attachMovie("recebe", "recebe"+i, vazio.getNextHighestDepth());
	/* Posicionamos o MovieClip */
	mc._x = Math.round(colunaAtual*mc._width+colunaAtual*5);
	mc._y = Math.round(linhaAtual*mc._height+linhaAtual*5);
	/* Deixamos o campo de texto dinamico nome_txt aumentar sozinho conforme o texto */
	mc.nome_txt.autoSize = true;
	/* Deixamos o campo de texto dinamico email_txt aumentar sozinho conforme o texto */
	mc.email_txt.autoSize = true;
	/* Mostramos o Nome */
	mc.nome_txt.text = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
	/* Mostramos o E-mail */
	mc.email_txt.text = xmlNode.childNodes[i].childNodes[1].firstChild.nodeValue;
	/* Mostramos a Data da postagem */
	mc.dia.text = xmlNode.childNodes[i].childNodes[2].firstChild.nodeValue;
	/* Mostramos o Comentário */
	mc.comentario_txt.text = xmlNode.childNodes[i].childNodes[3].firstChild.nodeValue;
	/* Colocamos os MovieClips importados no Array mcs pelo método push */
	mcs.push(mc);
	/* Incrementamos i e coluna */
	i++, colunaAtual++;
	/* Se colunaAtual for igual a quantidadeColuna e linhaAtual for menor que quantidadeLinha */
	if (colunaAtual == quantidadeColuna && linhaAtual<quantidadeLinha) {
		/* Zeramos a coluna */
		colunaAtual = 0;
		/* Incrementamos linha */
		linhaAtual++;
	}
	/* Se i for menor que total */ 
	if (i<total) {
		/* Chamamos a função preecher */
		preencher();
	}
	/* Se a altura do scrollBar for menor que altura do MovieClip vazio */ 
	if (scrollBar._height>vazio._height) {
		/* Deixamos o MovieClip scrollBar invisível */
		scrollBar._visible = false;
		/* Se não */
	} else {
		/* Deixamos o MovieClip scrollBar visível */
		scrollBar._visible = true;
	}
}
/* Função criaPaginacao */
function criaPaginacao() {
	/* Para a quantidadePagina */
	for (var paginas:Number = 0; paginas<quantidadePagina; paginas++) {
		/* Importamos o MovieClip pag_mc */
		var pg = paginacao.attachMovie("pag_mc", "p"+paginas, paginacao.getNextHighestDepth());
		/* Posicionamos ele */
		pg._x = Math.round(paginas*pg._width+paginas*3);
		/* Retorna o ponto em que se deve carregar as Mensagens */
		pg.idpag = paginas*(quantidadeColuna*quantidadeLinha);
		/* Numero da página */
		pg.pag_txt.text = paginas+1;
		/* Definimos a página atual */
		pg.atual = paginas;
		/* Ao clicar da página */
		pg.onRelease = function() {
			/* Retornamos a posição de origem do pan */
			scrollBar.pan._y = 20;
			/* Executa a função remove */
			remove();
			/* Execute a função ativar */
			ativar(this.atual);
			/* Deixamos a variável i igual ao id da paginação */
			i = this.idpag;
			/* Zeramos a variável colunaAtual */
			colunaAtual = 0;
			/* Zeramos a variável linhaAtual */
			linhaAtual = 0;
			/* Executa a função preencher */
			preencher();
		};
		/* Deixamos a primeira página ativada */
		paginacao.p0.onRelease();
	}
}
/* Função remove */
function remove():Void {
	/* Criamos um loop for para remover os MovieClips */
	for (var i:Number = 0; i<mcs.length; i++) {
		/* Removemos os MovieClips com o método removeMovieClip */
		mcs[i].removeMovieClip();
	}
	/* Zere o array mcs */
	mcs = [];
}
/* Função ativar */
function ativar(num:Number):Void {
	/* O loop for abaixo vai servir para definir quais dos MovieClips da paginação vão ficar habilitados, e o que ficará desabilitado */
	for (var i = 0; i<quantidadePagina; i++) {
		/* Se num for diferente de i */
		if (num != i) {
			/* Habilitamos as páginas */
			eval("paginacao.p"+i).enabled = true;
		} else {
			/* Desativamos as páginas */
			eval("paginacao.p"+i).enabled = false;
		}
	}
}
escrever.onPress = function() {
	gotoAndStop(2);
};

/* Paramos o filme */
stop();
/* Definimos a ordem de tabulação */
nome.tabIndex = 1;
email.tabIndex = 2;
comentario.tabIndex = 3;
enviar.tabIndex = 4;
limpar.tabIndex = 5;
/* Criamos um LoadVars que manda as informações ao PHP */
var objManda:LoadVars = new LoadVars();
/* Ao pressionar do botão enviar */
enviar.onPress = function() {
	/* Verificamos se o campo nome foi preenchido */
	if (nome.text == "") {
		/* Mostramos a mensagem de erro */
		status_txt.text = "Informe seu Nome";
		/* Se não, verificamos se o campo email foi preenchido */
	} else if (email.text == "") {
		/* Mostramos a mensagem de erro */
		status_txt.text = "Informe seu E-mail";
		/* Se não, verificamos se o campo email contém os caracteres @ e . */
	} else if (email.text.indexOf("@") == -1 || email.text.indexOf(".") == -1) {
		/* Mostramos a mensagem de erro */
		status_txt.text = "Informe corretamente seu E-mail";
		/* Se não, verificamos se o campo comentario foi preenchido */
	} else if (comentario.text == "") {
		status_txt.text = "Informe uma mensagem para enviar";
		/* Se todos os campos estiverem corretos */
	} else {
		/* Mostramos o status de Enviando Mensagem */
		status_txt.text = "Enviando Mensagem";
		/* Mandamos ao PHP os valores */
		/* O nome digitado no campo nome */
		objManda.nome = nome.text;
		/* O email digitado no campo email */
		objManda.email = email.text;
		/* O comentário digitado no campo comentario */
		objManda.comentario = comentario.text;
		/* Enviamos ao PHP os dados e carregamos as mensagens do PHP */
		objManda.sendAndLoad("http://natan-alves.t35.com/guestMx.php?action=cadastrar", objManda, "POST");
		/* Ao carregar o arquivo PHP */
		objManda.onLoad = function(ok) {
			/* Se carregou sem problemas */
			if (ok) {
				/* Mostramos a mensagem vinda do PHP */
				status_txt.text = this.mensagem;
				/* Apagamos os campos input */
				nome.text = "";
				email.text = "";
				comentario.text = "";
				intervalo = setInterval(volta, 2000);
			}
		};
	}
};
/* Ao pressionar do Botão limpar */
limpar.onPress = function() {
	/* Limpamos os campos input */
	nome.text = "";
	email.text = "";
	comentario.text = "";
	/* Limpamos o campo status_txt */
	status_txt.text = "";
};
/* Função volta */
function volta() {
	/* Voltamos ao primeiro frame */
	gotoAndStop(1);
	/* Acabamos com o intervalo */
	clearInterval(intervalo);
}
/* Ao pressionar do botão voltar */
voltar.onPress = function() {
	/* Voltamos ao primeiro frame */
	gotoAndStop(1);
	/* Acabamos com o intervalo */
	clearInterval(intervalo);
};