MXStudio » Leandro_Amano

Utilizando CSS com Flash

Leandro_Amano — Wed, 31 May 2006 00:00:00 +0000

Coluna Flash – Utilizando CSS com Flash

Introdução

Hoje vamos entender como o Flash exibe a leitura de um css externo anexado a um texto corrido. É muito útil quando temos muito texto no site e necessitamos atualiza-los de forma dinâmica… um exemplo disso seria você, desenvolvedor, criar dezenas de página, arredondemos para 60, e o cliente resolve que o texto não pode ser mais Verdana, corpo 10, cor 0×666666, e sim, Arial 11, 0×000000, o que fazer?…. A solução natural seria abrir todos os 60 arquivos e alterá-los um a um…. podem ver que o trabalho é no mínimo maçante (um saco), nesse caso, se o desenvolvedor fez o trabalho com CSS (Cascading Style Sheets) ele terá de alterar unicamente o css (um arquivo css), e não mais os 60 arquivos, dessa forma, quando o solicitador pedir para alterar propriedades do texto, você fará até com gosto a manutenção, já que agora ela não mais se tornará despendiosa!

Pré-Requisitos

Este artigo é básico, não é necessário conhecer ActionScript a fundo.
Nível Básico.

Arquivo Final

Objetivo

Aperfeiçoar técnicas de programação dentro do Flash 8.

Conteúdo

No Flash 8, abra um novo documento em branco.

Inicialmente, vamos abrir o painel de components (CTRL+F7), arraste dois TextArea, eles se encontram na árvore UI, onde estão os componentes para formulário.
O nome de instância dos objetos são: texto e exibe, onde texto mostrará o conteúdo textual e exibe mostrará as tags de css disponíveis no documento.
Esses componentes podem ser esticados para melhor visualização.

Abra o Dreamweaver 8, ou, caso não possua o bloco de notas:

Digite o seguinte texto:

.titulo {
font-family:Verdana, Arial, Helvetica, sans-serif;
font-size:14px;
color:#990000;
font-weight:bold;
}
corpo {
font-family:Verdana, Arial, Helvetica, sans-serif;
font-size:10;
color:#000000;
}
corpoDetalhe {
font-family:Verdana, Arial, Helvetica, sans-serif;
font-size:10;
color:#FF0000;
font-style:italic;
}

Nesse tutorial não entrarei em detalhes do css, mas para quem não conhece, basicamente aplicamos fontes, cores e tamanhos diferentes.
Salve-o como estilos.css na mesma pasta que vamos salvar o flash (isso não é obrigatório, porém, para aprendizado fica mais fácil).

Voltando ao Flash 8.

Com isso pronto, o resto é código, criem um novo layer de actions (~AS) e digitem:

/* Importamos a classe TextArea para utilizar o componente de visualização e edição de texto. */
import mx.controls.TextArea;
/* Importamos a classe StyleSheet para o css */
import TextField.StyleSheet;
/* Declaração dos 2 TextArea */
var exibe:TextArea;
var texto:TextArea;
/* Declaração do CSS */
var estilos:StyleSheet = new StyleSheet();
/* Lendo o arquivo .css */
estilos.load(“estilos.css”);
/* Quando ler o css o que fazer? */
estilos.onLoad = function(success:Boolean):Void {
if (success) {
/* Resposta: os campos TextArea poderão ler html e não serão editáveis */
exibe.html = true;
exibe.editable = false;
/* Exibe no TextArea os estilos css convertidos em String (getStylesNames retorna um array, precisamos passar para String, para exibição dos mesmos) */
exibe.text = estilos.getStyleNames().toString();
texto.html = true;
texto.editable = false;
/* No TextArea texto exibimos na propriedade styleSheet o próprio objeto css do onLoad */
texto.styleSheet = this;
/* Texto a ser exibido no texto: Como podemos observar, podemos aplicar os estilos usando o tradicional span class usado no html ou mesmo inserir via xml, com inserção de tags personalizadas, como boa regra de xhtml, toda tag aberta deve ser fechada, não esqueça nunca disso. */
texto.text = “Macromedia Flash 8
Estamos carregando um arquivo CSS externo.
O nome do arquivo é estilos.css.”;
}
};

É só salvar o documento na mesma pasta do css agora, a sugestão do nome é styleSheet.fla.
É só testar!

Obs.: Isso também pode (e deve) ser aplicado a textos chamados de fora.
Obs.2: Apesar deste artigo utilizar os componentes, isso não é necessário, aplique isso direto a campos dinâmicos.

Espero que tenham gostado e apliquem isso aos próximos trabalhos em Flash, dúvidas ou sugestões são bem vindas.
Abraços e até a próxima!

Download dos arquivos

Autor: Leandro Amano – Colunista de Flash do MXSTUDIO

Site: www.leandroamano.com.br
Leandro Amano é designer/desenvolvedor Adobe, iniciou sua carreira profissional em 1999, atualmente é Adobe User Group Leader do FlashFor, diretor de criação da Digital Bug e instrutor Oficial na ENG DTP & Multimídia, centro de treinamentos oficiais Adobe/Macromedia, onde ministra a tecnologia Adobe Flash em São Paulo – SP.

Movie Clip – HitTest (Galeria)

Leandro_Amano — Wed, 10 May 2006 00:00:00 +0000

Coluna Flash – Movie Clip – HitTest

Introdução

Um olá para todos os amigos do MXStudio.

Neste artigo vamos ver um pouco sobre o método HitTest da classe MovieClip, na verdade fiz este exemplo para um aluno há algum tempo e resolvi postar.

Para testar arraste uma miniatura para a área de exibição.

Pré-Requisitos

Este artigo pede um conhecimento básico de ActionScript, mas é necessário ter uma familiaridade com o Flash.

Objetivo

Aprimoramento da Action Script junto ao Flash 8.

Conteúdo

Incialmente, vamos ao Dreamweaver escrever um XML, para quem ainda não utiliza recomendo que leiam muito sobre isso.Muito é facilitado utilizando essa meta-linguagem que é portabilidade entre quaisquer sistemas.

Basicamente o que temos nesse xml são atributos para exibição de título, thumbnail e a imagem em seu tamanho maior. Em uma breve oportunidade veremos mais sobre a classe XML.

Salve o como galeria.xml.

Nosso trabalho no xml acaba aqui, o Flash se encarregará de ler esses dados. Não esquecendo que esse xml deveria ser gerado por um banco de dados, para fácil manutenção do mesmo.

No Flash 8, abra um novo documento (580px 510px) em branco.

Salve-o como galeria.fla.

Vamos inicialmente definir nossos elementos visuais, desenhe:

Um MovieClip de 378 de largura por 510 de altura, nome de instância: finalTarget;
Um MovieClip de qualquer tamanho (ele será seu preloader), nome de instância: preloader;
Va até o menu superior do Flash, clique em Insert, new Symbol, tipo MovieClip, nome item. Selecione o botão no canto inferior direito e selecione a opção Export For ActionScript, o Identifier deve ter o mesmo nome do símbolo, para facilitar sua localização numa Library complexa, neste caso item.
Dentro deste símbolo, inclua mais duas layers, nomes das três layers:

~AS
target_mc
title_txt

Na layer target_mc, desenhe mais um MovieClip de 100 de largura por 135 de altura, nome de instancia target_mc.
Na layer title_txt, desenhe um texto dinâmico com qualquer tamanho, nome de instância title_txt.

Esses sinais de _mc e _txt vão facilitar para que não esqueçamos o tipo desses objetos e também para lembrar que são variáveis de instâncias.

Na layer de actions digite:

/*Estamos importando a classe Tween para facilitar as animações via Action Script*/
import mx.transitions.Tween;
/*Declarando os tipos das instâncias visuais*/
var title_txt:TextField;
var target_mc:MovieClip;
/*Declarando as vriáveis não visuais*/
/*Indica se a thumb está dentro do container */
var selected:Boolean = false;
/*Indica se estamos arrastando a Thumb */
var isDragging:Boolean = false;
/*Posição inicial da Thumb */
var posX:Number = target_mc._x;
var posY:Number = target_mc._y;
/*Velocidade da animação do MovieClip via cálculo */
var time:Number = 10;
/*Inicialização dos objetos*/
/*Classe para preload das imagens grandes*/
var loader:MovieClipLoader = new MovieClipLoader();
/*Criação do objeto que irá ouvir os eventos da classe MovieClipLoader() */
var o:Object = new Object();
/*O MCL está cadastrando um objeto para receber seus futuros eventos */
loader.addListener(o);
/*Evento liberado ao iniciar um preload */
o.onLoadStart = function():Void {
with (_root.preloader) {
_alpha = 100;
}
};
/*Evento liberado no progresso do preload (carregando….) */
o.onLoadProgress = function(target:MovieClip, loaded:Number, total:Number):Void {
_root.preloader._xscale = loaded/total*100;
};
/*Evento liberado ao finalizar o preload, é aqui que coloco as ações que devem acontecer ao finalizar o preload */
o.onLoadInit = function():Void {
var effPreloader:Tween = new Tween(_root.preloader, “_alpha”, None.easeNone, _root.preloader._alpha, 0, .5, true);
var effTarget:Tween = new Tween(_root.finalTarget, “_alpha”, None.easeNone, 0, 100, .5, true);
};
/*Propriedades das instâncias*/
this.tabEnabled = false;
with (title_txt) {
html = true;
autoSize = true;
type = “dynamic”;
selectable = false;
}
/*Eventos do próprio Objeto*/
function onPress():Void {
/*Alterando o nível de altura do próprio MovieClip*/
this.swapDepths(_root.getNextHighestDepth());
target_mc.startDrag(false);
/*Estou arrastando */
isDragging = true;
}
function onRelease():Void {
target_mc.stopDrag();
/*Não estou arrastando mais */
isDragging = false;
/*Se o target_mc colidir com o FinalTarget que está no _root, faça algo*/
/*O HitTest passa outros parâmetros dependendo do caso: obj.hitTest(_x, _y, flag), onde flag indica se ele deve respeitar o bounding box (caixa delimetadora do MovieClip) ou não */
if (target_mc.hitTest(_root.finalTarget)) {
/*Aqui dizemos que ele continua sendo arrastado, mais abaixo vamos entender */
isDragging = true;
/*Estou selecionado agora que colidi com finalTarget */
selected = true;
/*Um loop básico que nada mais faz que liberar todos aqueles que não são o que eu estou arrastando*/
/*Para propriedade no _root faça */
for (var i in _root) {
/*Se o nome de instância do meu MovieClip no _root contiver item, faça… */
if (_root[i]._name.indexOf(“item”)>=0) {
/*Se o objeto nesse _root for eu mesmo faça… */
if (_root[i] == this) {
/*Aqui dentro o target_mc fica invisivel e o loader carrega minha variável largeImage, inserida pelo XML que já vamos ver */
this.target_mc._visible = false;
loader.loadClip(this.largeImage, _root.finalTarget);
/*Caso contrário */
} else {
/*Todos que não são eu mesmo não estão arrastando, não estão mais selecionados e voltam a ficar visíveis */
_root[i].isDragging = false;
_root[i].selected = false;
_root[i].target_mc._visible = true;
}
}
}
}
}
function onReleaseOutside():Void {
onRelease();
}
/*Esse evento de loop de “animação” verifica se minha condição isDragging (está arrastando) é verdadeira, se não for faça isso… */
function onEnterFrame():Void {
if (!isDragging) {
/*A posição do meu objeto será incrementada pela posição inicial menos a posição em que está, dividido pelo tempo de percurso, quanto menor, mais rápido */
target_mc["_x"] += (posX-target_mc["_x"])/time;
target_mc["_y"] += (posY-target_mc["_y"])/time;
}
}

Agora nosso item arrastável já funciona sozinho, o que temos de fazer é populá-lo com o XML, então, agora, voltemos ao _root.
No palco definiremos três layers com os seguintes nomes:

~AS
preloader
finalTarget

Em cada layer deixamos os respectivos objetos, nesse caso, não coloquei _mc para eles, mas seria bom que vocês o fizessem futuramente…
Na layer de Actions vamos ao código final:

/*Declarando os tipos das instâncias visuais*/
var preloader:MovieClip;
var finalTarget:MovieClip;
/*Propriedades das instâncias*/
/*Aqui estamos definindo um background para o finalTarget, seu depth (nível, aqui não podemos dizer, suba duas layers, deça três…) que será o mesmo do finalTarget menos um. */
finalTarget.duplicateMovieClip(“bgTarget”, finalTarget.getDepth()-1);
/*Declaração de funções*/
function createGallery():Void {
/*Criação do objeto XML */
var xml:XML = new XML();
xml.ignoreWhite = true;
/*Carregando nosso arquivo xml */
xml.load(“galeria.xml”);
/*Ao ler o xml faça isso */
xml.onLoad = function(success:Boolean):Void {
if (success) {
var path:Object = this.firstChild.childNodes;
/*Para variável i que vale 0, enquanto ela for menor que o número de itens dentro do xml, incremente 1 */
for (var i:Number = 0; i /*Estamos chamando o item da Library */
t = _root.attachMovie(“item”, “item”+i, i, {_x:10});
/*Esse item terá sua instância title_txt em sua propriedade text o valor alterado para o atributo title do XML */
t.title_txt.text = path[i].attributes.title;
/*Esse item terá sua instância target_mc carregando via loadMovie o atributo thumb do XML */
t.target_mc.loadMovie(path[i].attributes.thumb);
/*Anexamos uma variável largeImage ao MovieClip item, a mesma que chamamod no método loadClip da classe MovieClipLoader dentro do item */
t.largeImage = path[i].attributes.img;
/*Definimos a posição do item e incrementamos um espaço de px a distância entre eles */
t._y = i*t._height+10;
}
}
};
}
/*Inicialização das funções */
createGallery();

Neste artigo não vimos a paginação deste xml, ficará para a parte 2 juntamente com os Downloads dessas imagens.

Espero que tenham gostado, dúvidas ou sugestões são bem vindas em meu e-mail.

Abraços e até a próxima!

Autor: Leandro Amano – Colunista de Flash do MXSTUDIO

Site: www.leandroamano.com.br
Sobre: Leandro Amano atualmente é designer/desenvolvedor Macromedia, Macromedia User Group Leader do Flashfor, diretor de criação da Digital Bug e instrutor Macromedia na ENG DTP & Multimídia em São Paulo – SP.

Qualquer dúvida envie um email para amano@leandroamano.com.br ou acesse o nosso fórum.

Flash Vídeo – Media Components

Leandro_Amano — Tue, 09 May 2006 00:00:00 +0000

Coluna Flash – Flash Vídeo – Media Components

Flash Platform – Developing a Simple Rich Media Player
Desenvolvendo um Simples Tocador de Vídeo em Flash 8

Introdução

Estaremos definindo neste artigo algo mais concreto sobre Flash 8 e vídeo, mídia rica que nenhum outro pode propor, tanto em facilidade de desenvolvimento como retorno em menor prazo.

Pré-Requisitos

Este artigo pede um conhecimento básico de ActionScript, mas é necessário ter uma familiaridade com o Flash.

Objetivo

Definir o uso de Flash Vídeo com e sem servidor, utilizando novos componentes providos junto ao Flash 8.

Conceitos

O Flash 8 trabalha diferentemente dos seus antecessores com vídeo, nesta versão qualquer um pode trabalhar com download progressivo de maneira profissional. No momento da importação o Flash já nos traz a opção desse tipo de uso com vídeo, mas não entrarei em detalhes sobre isso aqui.

Estaremos utilizando o formato .flv nos vídeos que é o único formato real de vídeo no Flash.
A vantagem de se utilizar esse formato, é que a Frame Rate do vídeo pode ser diferente a do seu filme principal, além da distribuição externa de arquivos, é claro. Mas a principal vantagem que considero é a possibilidade de streaming real, que na versão MX só era possível com o Macromedia Flash Communication Server, como as actions netConnection e netStream. Não vamos esquecer que o Flash 8 suporta vídeo com canal Alpha e filtros aplicados dentro do próprio Flash!

Mas, o que e Streaming? Streaming e a distribuição em tempo real de vídeo ao vivo ou áudio na internet. Esse streaming só pode ser transferido com o Flash utilizando o Macromedia Flash Media Server 2 (ou Macromedia Flash vídeo Streaming Service). A buferização é usada para armazenar dados, antes que o streaming comece a tocar ou continue tocando.
Vídeos digitais são codificados e decodificados usando um CODEC (CODEC=COmpression (compressão) / DECompression (descompressão)). V ídeos e áudios utilizam diferentes CODECs, mas são compilados dentro de um único arquivo, o player precisa do mesmo CODEC para que possa ser assistido.

Então a vantagem do Flash 8. A nova versão já traz consigo o Macromedia Flash 8 vídeo Encoder que converte AVI, MOV, WMV, DV, MPEG em FLV, neste caso o cliente necessita apenas do mesmo Flash Player para visualizar esse conteúdo rico.
Algumas das vantagens que a Macromedia traz com o Flash:

Nenhum JavaScript complexo e requerido;
Não necessita de checagem de plataforma;
Não necessita de pop up;
Rápida buferização e play
100% de controle sobre o player ;
O player é facilmente controlado com ActionScript;
Player 100% customizável;
Captura de vídeo (fire-wire cameras, USB cameras, microfones);

Agora que conhecemos uma leve camada superficial sobre vídeo e alguns conceitos, vamos desenvolver um mini player

Conteúdo

No Macromedia Flash 8, num novo Flash Document:

Já iremos criar as layers que iremos trabalhar, algumas boas convenções a serem seguidas:

A layer do topo deve ser a de ActionScript, uso o nome as;
Layers nunca são chamadas por actions, logo o nome descritivo deve sempre ser alterado de forma que fique fácil de entender, não importando espaços e acentuações;
Layers que não são usadas em tempo de execução devem ser alteradas para “guides”, para isso é só clicar com o direito sobre a layer e pedir guide;

Em nossas layers:
Na layer do topo, vamos chamar a layer de ~AS(actionScript).
Também criaremos mais três layers: UI Components, FLV Playback e controles, a ordem de cima para baixo é:

as (corrigir para ~AS)
UI Components
FLV Playback
controles

Em seguida, abriremos o painel de componentes, o caminho é: Window - Components.
Com o painel aberto, abra o nó da árvore FLV Playback - Player 8 e arraste o FLVPlayback para sua respectiva layer.
Reparem que como todo componente, na aba parameters na barra de propriedades, o componente possui uma série de configurações que facilitam o desenvolvimento, esses detalhes não entram no escopo desse artigo, o que devemos saber é unicamente são as seguintes opções:

autoPlay - começar tocando? true para sim e false para não;
contentPath - arquivo .flv que será utilizado para o componente de vídeo, em nosso caso não definiremos via parâmetro;
skin - essa opção pode definir vários estilos de personalização do player, porém, todos padrões, não é essa nossa intenção, utilizaremos None;
maintainAspectRatio - Utilizaremos false para que o vídeo tenha sempre a mesma proporção;

import mx.video.FLVPlayback;
var _playback:FLVPlayback;

Estamos importando a classe FLVPlayback e identificando o objeto visual que estará associado a classe, isso nos permite acessar as propriedades e métodos dos componentes mais facilmente.
Através das actions abaixo vamos dizer ao Flash qual filme chamar:

_playback.contentPath = “sampleFLV/video.flv”;

Note que no contentPath, coloquei o vídeo em uma pasta separada, de nome sampleFLV. Isso adota uma prática importante de organização de arquivos do aplicativo. O nome do arquivo será o arquivo de cada um, no meu caso o mesmo se chama video.flv.

Vamos abrir novamente o painel de componentes e arrastar para a layer UI Components dois componentes List, que se encontram no nó User Interface, esses componentes terão os nomes de instâncias _filmes e _capitulos.
Dentro do componente _filmes vamos editar seus labels e datas, que nada mais são que respectivamente rótulos e dados que serão armazenados, onde no caso de filmes, labels guardará os nomes descritivos dos filmes e data o endereço dos filmes.
Para o componente _capitulos, iremos armazenar nomes descritivos para os capítulos do filme correspondente e em data armazenaremos o tempo que corresponde a entrada do capítulo, por exemplo 5 (5 segundos).

As configurações para _filmes são:

Label: Baby, Montain, Jamie;
Data: sampleFlv/adrian.flv, sampleFlv/MtnBike.flv, sampleFLV/Jamie_on_White.flv;

As configurações para _capitulos são:

Label: Capítulo 1, Capítulo 2, Capítulo 3, Capítulo 4;
Data: 0, 15, 30, 45;

Os capítulos são meramente ilustrativos, cada um deve considerar seu próprio filme em questão e configurar o tempo correspondente a sua mídia.

Agora que estão configurados devemos fazer com que funcionem junto ao componente de vídeo FLVPlayback, para isso abrimos a janela - Window - Component Inspector com _filmes selecionado. Na aba Bindings (relacionamentos) vamos agora dizer ao List (_filmes) que o mesmo será relacionado junto ao FLVPlayback (_playback), para isso, vamos clicar no sinal de + (positivo) e adicionar o SelectedItem, clicar na opção abaixo Use Path Expression e digitar data, já que nossos dados estão armazenados na propriedade data do componente List, clique em OK.
Nas opções abaixo direction, bound to... vamos deixar direction como out, já que o mesmo vai sair do componente List e entrar no componente Playback, em bound to selecionamos o componente FLVPlayback e pedimos o contentPath, já que é ele quem nos diz que filme será tocado.
No componente _capitulos devemos fazer a mesma coisa, com exceção que ao final o SelectedItem.data será relacionado com playheadTime em bound to.

Apenas isso já resolve boa parte de nossos problemas, podemos até testá-lo. O filme já está funcionando com os componentes UI!
A partir de agora vamos customizar nosso tocador de Vídeo.
Na layer controles iremos agora arrastar alguns componentes novos, abriremos novamente Window - Components, no nó FLV Playback Custom UI vamos trazer:

PlayButton;
PauseButton;
StopButton;
SeekBar;
VolumeBar;
MuteButton;

_playback.playButton = _play;
_playback.pauseButton = _pause;
_playback.stopButton = _stop;
_playback.seekBar = _seek;
_playback.volumeBar = _volume;
_playback.muteButton = _mute;

Podemos testar e ver como reage com esses novos componentes, e um detalhe muito importante, com dois cliques nesses componentes de navegação, podemos editar formas e cores personalizadas, como acontecia com os componentes UI na versão MX. Tudo isso com apenas nove linhas de ActionScript.

Na layer de ActionScript iremos agora adicionar alguns eventos que nos informam eventos ocorridos durante a execução:

/*Estamos criando o campo de texto*/
var texto:TextField = _root.createTextField(“info”, _root.getNextHighestDepth(), 11, 340, 0, 0);
/*O texto será auto dimensionável a partir da esquerda*/
texto.autoSize = “left”;
/*O texto não será selecionável*/
texto.selectable = false;
/*Estamos criando o estilo para o campo de texto*/
var estilo:TextFormat = new TextFormat();
/*Fonte*/
estilo.font = “Verdana”;
/*Tamanho*/
estilo.size = 12;
/*Negrito*/
estilo.bold = true;
/*Cor do texto*/
estilo.color = 0×990000;
/*Sublinhado*/
estilo.underline = true;

Agora que já temos nosso texto precisamos adicionar eventos e conforme a ocorrência apresenta-los no campo de texto, nosso componente possui alguns eventos, como ready e stateChange, veremos algo muito breve sobre isso. Assim como todo componente devemos adicionar ou objeto genérico que fica prestando atenção a eventos que ocorrem com o Objeto, é ele quem nasce exclusivamente para escutar esses eventos, chamaremos ele de ouvidor:

var ouvidor:Object = new Object();

Agora que está criado nosso objeto (abaixo das actions anteriores) devemos aplicar a este objeto os eventos que escutaremos, no caso ready e stateChange:

ouvidor.ready = function():Void {
//Exibe o tempo total do filme
texto.text = “Tempo total: “+_playback.totalTime;
//Aplica o estilo ao texto
texto.setTextFormat(estilo);
};
ouvidor.stateChange = function():Void {
//Exibe o estado do filme, como por exemplo tocando, pausado, etc
texto.text = _playback.state;
//Aplica o estilo ao texto
texto.setTextFormat(estilo);
};

Aplicando agora o objeto ouvidor ao componente utilizado:

_playback.addEventListener(“ready”, ouvidor);
_playback.addEventListener(“stateChange”, ouvidor);

Nosso código final é esse:

import mx.video.FLVPlayback;
var _playback:FLVPlayback;
_playback.contentPath = “sampleFLV/betina.flv”;
_playback.playButton = _play;
_playback.pauseButton = _pause;
_playback.stopButton = _stop;
_playback.seekBar = _seek;
_playback.volumeBar = _volume;
_playback.muteButton = _mute;
//Estamos criando o campo de texto
var texto:TextField = _root.createTextField(“info”, _root.getNextHighestDepth(), 11, 340, 0, 0);
//O texto será auto dimensionável a partir da esquerda
texto.autoSize = “left”;
//O texto não será selecionável
texto.selectable = false;
//Estamos criando o estilo para o campo de texto
var estilo:TextFormat = new TextFormat();
//Fonte
estilo.font = “Verdana”;
//Tamanho
estilo.size = 12;
//Negrito
estilo.bold = true;
//Cor do texto
estilo.color = 0×990000;
//Sublinhado
estilo.underline = true;
var ouvidor:Object = new Object();
ouvidor.ready = function():Void {
//Exibe o tempo total do filme
texto.text = “Tempo total: “+_playback.totalTime;
//Aplica o estilo ao texto
texto.setTextFormat(estilo);
};
ouvidor.stateChange = function():Void {
//Exibe o estado do filme, como por exemplo tocando, pausado, etc
texto.text = _playback.state;
//Aplica o estilo ao texto
texto.setTextFormat(estilo);
};
_playback.addEventListener(“ready”, ouvidor);
_playback.addEventListener(“stateChange”, ouvidor);

www.leandroamano.com.br
Sobre: Leandro Amano atualmente é designer/desenvolvedor Macromedia, Macromedia User Group Leader do Flashfor, diretor de criação da Digital Bug e instrutor Macromedia na ENG DTP & Multimídia em São Paulo – SP.

Qualquer dúvida envie um email para amano@leandroamano.com.br ou acesse o nosso fórum.

MXStudio » Leandro_Amano

Utilizando CSS com Flash

Coluna Flash – Utilizando CSS com Flash

Introdução

Pré-Requisitos

Arquivo Final

Objetivo

Conteúdo

Movie Clip – HitTest (Galeria)

Coluna Flash – Movie Clip – HitTest

Introdução

Pré-Requisitos

Objetivo

Conteúdo

Flash Vídeo – Media Components

Coluna Flash – Flash Vídeo – Media Components

Flash Platform – Developing a Simple Rich Media Player Desenvolvendo um Simples Tocador de Vídeo em Flash 8

Introdução

Pré-Requisitos

Objetivo

Conceitos

Conteúdo

Flash Platform – Developing a Simple Rich Media Player
Desenvolvendo um Simples Tocador de Vídeo em Flash 8